AnteriorSiguiente

Key.addListener()

Disponibilidad

Flash Player 6.

Sintaxis

Key.addListener (newListener)

Parámetros

newListener Objeto con los métodos onKeyDown y onKeyUp.

Valor devuelto

Ninguno.

Descripción

Método; registra un objeto para que reciba una notificación de onKeyDown y onKeyUp. Al presionar o soltar una tecla, sin tener en cuenta la selección de entrada, se invoca el método onKeyDown u onKeyUp de todos los objetos de detección registrados con addListener(). Varios objetos pueden detectar notificaciones de teclado. Si el detector newListener ya está registrado, no se produce ningún cambio.

Ejemplo

En este ejemplo se crea un nuevo objeto detector y define una función para onKeyDown y onKeyUp. La última línea utiliza el método addListener() para registrar el detector con el objeto Key para que pueda recibir notificación de los eventos presionar tecla y soltar tecla. 

myListener = new Object();
myListener.onKeyDown = function () {
  trace ("You pressed a key.");
}
myListener.onKeyUp = function () {
  trace ("You released a key.");
}
Key.addListener(myListener);

En el ejemplo siguiente se asigna el método abreviado de teclado Control+7 a un botón cuyo nombre de instancia es myButton y se ofrece información sobre el método abreviado disponible para los lectores de pantalla (consulte _accProps). En este ejemplo, cuando presiona Control+7 la función myOnPress muestra el texto "hello" en el panel Salida; en el archivo, puede crear una función que realice una tarea de más relevancia. 

function myOnPress() {
  trace( "hello" );
}

function myOnKeyDown() {
  if (Key.isDown(Key.CONTROL) && Key.getCode() == 55) // 55 is key code for 7
  {
    Selection.setFocus( myButton );
    myButton.onPress();
  }
}

var myListener = new Object();
myListener.onKeyDown = myOnKeyDown;
Key.addListener( myListener );

myButton.onPress = myOnPress;
myButton._accProps.shortcut = "Ctrl+F"
Accessibility.updateProperties();

Véase también

Key.getCode(), Key.isDown(), Key.onKeyDown, Key.onKeyUp, Key.removeListener()

AnteriorSiguiente