| |
| |
| |
| |
Flash Player 7.
my_mcl.loadClip("url",target)
url URL absoluta o relativa del archivo SWF o JPEG que se debe cargar. Una ruta relativa debe ser relativa respecto al archivo SWF del nivel 0. Las URL absolutas deben incluir la referencia al protocolo, como http:// o file:///. Los nombres de archivo no pueden incluir especificaciones de unidad de disco.
target Ruta de destino de un clip de película o número entero que especifica el nivel de Flash Player en el que se cargará la película. El clip de película de destino se sustituirá por la imagen o película cargada.
Ninguno.
Método; carga archivos SWF o JPEG en un clip de película de Flash Player mientras se reproduce la película original. El método loadMovie() permite ver varias películas al mismo tiempo y pasar de una película a otra sin cargar otro documento HTML.
La utilización de este método en lugar de loadMovie() o MovieClip.loadMovie() ofrece varias ventajas:
MovieClipLoader.onLoadStart() se invoca cuando se inicia la carga.MovieClipLoader.onLoadError() se invoca si no se puede cargar el clip.MovieClipLoader.onLoadProgress() se invoca a medida que evoluciona el proceso.MovieClipLoader.onLoadInit() se invoca después de que se hayan ejecutado las acciones del primer fotograma del clip, de forma que puede empezar a manipular el clip cargado.Una película o imagen cargada en un clip de película hereda las propiedades de posición, rotación y escala del clip de película. Puede utilizar la ruta de destino del clip de película para acceder a la película cargada.
Puede utilizar este método para cargar uno o más archivos en un clip de película o en un nivel. La instancia del clip de película destino que se pasa como parámetro a los objetos detectores MovieClipLoader. En su lugar, puede crear un objeto MovieClipLoader diferente para cada archivo que cargue.
Utilice MovieClipLoader.unloadClip() para eliminar películas o imágenes cargadas mediante este método o para cancelar una operación de carga que esté en curso.
En el ejemplo siguiente se muestra el uso de muchos de los métodos y detectores MovieClipLoader.
// primer conjunto de detectores
var my_mcl = new MovieClipLoader();
myListener = new Object();
myListener.onLoadStart = function (target_mc)
{
myTrace ("*********First my_mcl instance*********");
myTrace ("Your load has begun on movie clip . = " + target_mc);
var loadProgress = my_mcl.getProgress(target_mc);
myTrace(loadProgress.bytesLoaded + " = bytes loaded at start");
myTrace(loadProgress.bytesTotal + " = bytes total at start");
}
myListener.onLoadProgress = function (target_mc, loadedBytes, totalBytes)
{
myTrace ("*********First my_mcl instance Progress*********");
myTrace ("onLoadProgress() called back on movie clip " + target_mc);
myTrace(loadedBytes + " = bytes loaded at progress callback " );
myTrace(totalBytes + " = bytes total at progress callback \n");
}
myListener.onLoadComplete = function (target_mc)
{
myTrace ("*********First my_mcl instance*********");
myTrace ("Your load is done on movie clip = " + target_mc);
var loadProgress = my_mcl.getProgress(target_mc);
myTrace(loadProgress.bytesLoaded + " = bytes loaded at end" );
myTrace(loadProgress.bytesTotal + " = bytes total at end=");
}
myListener.onLoadInit = function (target_mc)
{
myTrace ("*********First my_mcl instance*********");
myTrace ("Movie clip = " + target_mc + " is now initialized");
// ahora puede llevar a cabo la configuración necesaria, por ejemplo:
target_mc._width = 100;
target_mc._width = 100;
}
myListener.onLoadError = function (target_mc, errorCode)
{
myTrace ("*********First my_mcl instance*********");
myTrace ("ERROR CODE = " + errorCode);
myTrace ("Your load failed on movie clip = " + target_mc + "\n");
}
my_mcl.addListener(myListener);
//Ahora cargue los archivos en sus destinos.
// cargas en los clips de película - cadenas utilizadas como destino
my_mcl.loadClip("http://www.somedomain.somewhere.com/someFile.swf","_root.myMC");
my_mcl.loadClip("http://www.somedomain.somewhere.com/someOtherFile.swf", "_level0.myMC2");
//error en la carga
my_mcl.loadClip("http://www.somedomain.somewhere.com/someFile.jpg", _root.myMC5);
// carga en clips de película - instancias de clip de película utilizadas como destino.
my_mcl.loadClip("http://www.somedomain.somewhere.com/someOtherFile.jpg", _level0.myMC3);
// carga en _level1
my_mcl.loadClip("file:///C:/media/images/somePicture.jpg", 1);
//Segundo conjunto de detectores
var another_mcl = new MovieClipLoader();
myListener2 = new Object();
myListener2.onLoadStart = function (target_mc)
{
myTrace("*********Second my_mcl instance*********");
myTrace ("Your load has begun on movie clip22 . = " + target_mc);
var loadProgress = my_mcl.getProgress(target_mc);
myTrace(loadProgress.bytesLoaded + " = bytes loaded at start" );
myTrace(loadProgress.bytesTotal + " = bytes total at start");
}
myListener2.onLoadComplete = function (target_mc)
{
myTrace ("*********Second my_mcl instance*********");
myTrace ("Your load is done on movie clip = " + target_mc);
var loadProgress = my_mcl.getProgress(target_mc);
myTrace(loadProgress.bytesLoaded + " = bytes loaded at end");
myTrace(loadProgress.bytesTotal + " = bytes total at end" );
}
myListener2.onLoadError = function (target_mc, errorCode)
{
myTrace ("*********Second my_mcl instance*********");
myTrace ("ERROR CODE = " + errorCode);
myTrace ("Your load failed on movie clip = " + target_mc + "\n");
}
another_mcl.addListener(myListener2);
//Ahora cargue los archivos en sus destinos (utilizando la segunda instancia de MovieClipLoader)
another_mcl.loadClip("http://www.somedomain.somewhere.com/yetAnotherFile.jpg", _root.myMC4);
// Emita las sentencias siguientes después de completar la descarga,
// y después de llamar a my_mcl.onLoadInit.
// my_mcl.removeListener(myListener)
// my_mcl.removeListener(myListener2)
| |
| |
| |
| |