interface

Disponibilidad

Flash Player 6.

Sintaxis

interface InterfaceName {}
interface InterfaceName [extends InterfaceName [, InterfaceName ...] {}

Nota: para utilizar esta palabra clave, debe especificar ActionScript 2.0 y Flash Player 6 o posterior en la ficha Flash del cuadro de diálogo Configuración de publicación del archivo FLA. Esta palabra clave sólo se admite si se utiliza en archivos de script externos, no en scripts escritos en el panel Acciones.

Descripción

Palabra clave; define una interfaz. Una interfaz es parecida a una clase, con las diferencias importantes que se indican a continuación:

• Las interfaces sólo contienen declaraciones de los métodos, no de su implementación. Es decir, cada clase que implementa una interfaz debe proporcionar una implementación para cada uno de los métodos declarados en la interfaz.
• En una definición de interfaz sólo pueden utilizarse miembros públicos. Además, no se permiten miembros de clase e instancia.
• No se permiten las sentencias get y set en las definiciones de interfaz.

Para más información, consulte Creación y utilización de interfaces.

Ejemplo

En el ejemplo siguiente se muestran varias formas de definir e implementar interfaces.

(archivos .as Ia, B, C, Ib, D, Ic, E del paquete de nivel superior)

// archivo Ia.as
interface Ia
{
  function k():Number;         // declaración de método únicamente
  function n(x:Number):Number; // sin implementación 
}
// archivo B.as
class B implements Ia
{
  function k():Number {return 25;}
  function n(x:Number):Number {return x+5;}
} 
// script externo o panel Acciones
var mvar:B = new B();
trace(mvar.k());   // 25
trace(mvar.n(7)); // 12

// archivo c.as
class C implements Ia 
{
  function k():Number {return 25;}
} // error: la clase debe implementar todos los métodos de interfaz

// archivo Ib.as
interface Ib
{
  function o():Void;
} 
class D implements Ia, Ib
{
  function k():Number {return 15;}
  function n(x:Number):Number {return x*x;}
  function o():Void {trace("o");} 
} 

// script externo o panel Acciones
mvar = new D();
trace(D.k());   // 15
trace(D.n(7));  // 49
trace(D.o());   // "o"

interface Ic extends Ia
{
  function p():Void;
} 
class E implements Ib, Ic
{
  function k():Number {return 25;}
  function n(x:Number):Number {return x+5;}
  function o():Void {trace("o");} 
  function p():Void {trace("p");} 
} 

Véase también

class, extends, implements